Tüm yazılarTürkçe

CMake baş ağrıtmasın

CMake logosu

C++ ile uğraşınca yolunuz dönüp dolaşıp CMake’e çıkıyor. Premake gibi alternatifler var. Hatta xmake gibi, ayarları gerçek bir programlama diliyle yazdıranlar da var. Yine de ben bütün C++ projelerimde CMake kullanıyorum, birlikte çalıştığım ekiplere de sık sık öneriyorum. C++ dünyasında bulduğum şu bir parça standarda fazla bağlanmış olabilirim.

Bir projeye yeni girdiğimde, bir derleme ayarının nereden geldiğini anlamak için bütün CMakeLists.txt dosyalarını dolaşmak istemiyorum. Modern CMake’in işime yarayan tarafı tam burada. Her hedefin kaynak dosyalarını, ayarlarını ve bağımlılıklarını bir arada görebiliyorum. Aşağıda bir projeye başlarken işime yarayan komutları ve kendi kullandığım yardımcı fonksiyonu anlatıyorum. İşin ayrıntısına girmek isterseniz Craig Scott’ın kitabı ile yazının sonundaki kaynaklara bakabilirsiniz.

Modern CMake’te işe hedeften başlayın

Önce ortaya ne çıkacağını düşünün. Program için add_executable, kütüphane için add_library ile bir hedef tanımlayın. Sonra her ayarı ilgili hedefe bağlayın.

  • Kaynak dosyaları ve başlık arama yolları için target_sources ve target_include_directories.
  • Derleyici seçenekleri ve önişlemci tanımları için target_compile_options ve target_compile_definitions.
  • Bağlayıcı seçenekleri ve kütüphaneler için target_link_options ve target_link_libraries.
  • Önceden derlenen başlıklar ve diğer hedef özellikleri için target_precompile_headers ve set_target_properties.

include_directories ve link_libraries gibi dizin kapsamına yayılan komutları mümkün olduğunca az kullanın. Bir kütüphanenin hangi programa bağlandığını anlamak için o programın hedef tanımına bakmak yeterli olsun.

find_package paketi nasıl buluyor?

Diyelim ki myapp programında SDL2_ttf kullanacaksınız. Önce CMake’e paketi bulmasını söylüyor, sonra paketin sunduğu hedefi kendi programınıza bağlıyorsunuz.

find_package(SDL2_ttf REQUIRED)
target_link_libraries(myapp PRIVATE SDL2_ttf::SDL2_ttf)

Bu iki satırın arkasında CMake dosyaları var. Bunların bir kısmı CMake’le birlikte gelen Find<Paket>.cmake modülleri, bir kısmı da paketin kurulumuyla gelen yapılandırma dosyaları. Örneğin Linux’ta aşağıdaki komutlarla sistemdeki modülleri ve -config.cmake biçimindeki yapılandırma dosyalarını arayabilirsiniz.

find / -name "*-config.cmake" 2>/dev/null
find / -name "Find*.cmake" 2>/dev/null

Arama sonucunda şöyle yollar görebilirsiniz.

/usr/share/cmake/bash-completion/bash-completion-config.cmake
/usr/lib/x86_64-linux-gnu/cmake/harfbuzz/harfbuzz-config.cmake
/usr/lib/x86_64-linux-gnu/cmake/SDL2_ttf/sdl2_ttf-config.cmake
/usr/lib/x86_64-linux-gnu/cmake/SDL2/sdl2-config.cmake
...

Paket değişkeni mi, CMake hedefi mi?

Her paket aynı arayüzü sunmuyor. Örneğin CMake’in Lua’yı bulmak için kullandığı modül, kütüphane yollarını LUA_LIBRARIES gibi değişkenlerde veriyor. Hangi değişkenleri tanımladığını FindLua belgelerinde görebilirsiniz.

find_package(Lua REQUIRED)
target_link_libraries(myapp PRIVATE ${LUA_LIBRARIES})

Bazı paketler ise doğrudan bağlayabileceğiniz bir CMake hedefi sunuyor. Örneğin SDL2’nin kendi paket yapılandırmasını kullanmak için CONFIG belirtebilir, ardından SDL2::SDL2 hedefine bağlanabilirsiniz.

find_package(SDL2 REQUIRED CONFIG)
target_link_libraries(myapp PRIVATE SDL2::SDL2)

CMake’le birlikte gelen modüllerin listesi de CMake belgelerinde var.

Bağımlılıkları projeye katmanın yolları

  • find_package. Sistemde kurulu bir kütüphaneyi kullanmak istediğimde ilk baktığım yol bu. CMake’in paketi bulabilmesi için bir arama modülü ya da paket yapılandırması gerekiyor.
  • git submodule ve add_subdirectory. Bağımlılığın kendi CMakeLists.txt dosyası varsa kaynak kodunu projeye ekleyip hedeflerini yerelde derleyebilirsiniz.
  • FetchContent ve ExternalProject_Add. Kaynakları bir Git alt modülüyle yönetmek yerine CMake’e aldırabilirsiniz. ExternalProject_Add ile kendi derleme komutları olan haricî projeleri de ayrı bir adımda derletebilirsiniz.

Bir başka seçenek vcpkg ya da Conan gibi bir paket yöneticisi. Bu araçlar çoğu zaman paketleri find_package üzerinden erişilebilir kılıyor. Kurulumda paket yöneticisinin sağladığı CMake araç zinciri dosyasını kullanabiliyorsunuz.

Ben uyumlu bağımlılıklar için CPM kullanıyorum. Geri kalanları sistemin paket yöneticisine bırakıyorum. Docker ile derleme ortamını zaten sabit tutabiliyorsam, sırf bağımlılıkları yönetmek için bir araç daha eklemek her zaman işimi kolaylaştırmıyor.

Hedef tanımını kısaltmak için pio_add_target

Her hedefe aynı derleyici seçeneklerini tekrar tekrar yazmamak için küçük bir fonksiyon kullanıyorum. Bir program eklerken çağrı şöyle görünüyor.

pio_add_target(
  NAME "myapp"
  IS_EXE
  SRC_PRIVATE ${MYAPP_SRC_FILES}
  INCLUDE_PUBLIC "include"
  INCLUDE_PRIVATE "src"
  LINK_PRIVATE "SDL2::SDL2;SDL2_ttf::SDL2_ttf")

IS_EXE verdiğimde program, diğer durumda kütüphane tanımlıyor. C++17 ve C11 ayarlarını, derleyici uyarılarını, sanitizer seçeneklerini ve clang-tidy ayarını tek yerde topluyor. Kaynak dosyalarını, başlık yollarını ve bağlanacak kütüphaneleri de ilgili hedef komutlarına iletiyor.

Adlandırılmış argümanları cmake_parse_arguments ile ayırıyorum. Bu komutun nasıl kullanıldığını çözmek, işin adındaki baş ağrısına en çok yaklaştığım yer olabilir. Derleyici seçenekleri ve sanitizer ayarları örnekte sabit. Kendi projenizde bunları ihtiyacınıza göre düzenleyebilirsiniz. Örnekteki pio_log ise projedeki günlükleme fonksiyonum.

function(pio_add_target)
  cmake_parse_arguments(
    PARSED_ARGS
    "IS_EXE"
    "NAME"
    "INCLUDE_PUBLIC;INCLUDE_PRIVATE;LINK_PUBLIC;LINK_PRIVATE;SRC_PUBLIC;SRC_PRIVATE"
    ${ARGN})

  set(cc_sanitizers
      -fsanitize=address
      # -fsanitize=memory -fsanitize=thread
      -fsanitize=undefined)
  set(cc_opts
      ${cc_sanitizers}
      # -w
      -fno-rtti -fno-exceptions -Wall -Wextra
      -Wshadow)

  if(${PARSED_ARGS_IS_EXE})
    pio_log("adding executable: ${PARSED_ARGS_NAME}")
    add_executable(${PARSED_ARGS_NAME})
  else()
    pio_log("adding library: ${PARSED_ARGS_NAME}")
    add_library(${PARSED_ARGS_NAME})
  endif()

  # set language standards
  target_compile_features(${PARSED_ARGS_NAME} PRIVATE cxx_std_17)
  set_target_properties(${PARSED_ARGS_NAME} PROPERTIES CXX_EXTENSIONS OFF)
  set_target_properties(${PARSED_ARGS_NAME} PROPERTIES C_STANDARD 11)
  set_target_properties(${PARSED_ARGS_NAME} PROPERTIES C_EXTENSIONS OFF)

  # compiler options
  target_compile_options(${PARSED_ARGS_NAME} PRIVATE ${cc_opts})

  # sources
  target_sources(${PARSED_ARGS_NAME} PUBLIC ${PARSED_ARGS_SRC_PUBLIC})
  target_sources(${PARSED_ARGS_NAME} PRIVATE ${PARSED_ARGS_SRC_PRIVATE})

  # includes
  target_include_directories(${PARSED_ARGS_NAME}
                             PUBLIC ${PARSED_ARGS_INCLUDE_PUBLIC})
  target_include_directories(${PARSED_ARGS_NAME}
                             PRIVATE ${PARSED_ARGS_INCLUDE_PRIVATE})

  # links
  target_link_libraries(${PARSED_ARGS_NAME} PUBLIC ${PARSED_ARGS_LINK_PUBLIC})
  target_link_libraries(${PARSED_ARGS_NAME} PRIVATE ${PARSED_ARGS_LINK_PRIVATE})

  # clang-tidy
  set_target_properties(${PARSED_ARGS_NAME} PROPERTIES CXX_CLANG_TIDY
                                                       "clang-tidy")
  set_target_properties(${PARSED_ARGS_NAME} PROPERTIES C_CLANG_TIDY
                                                       "clang-tidy")

  # sanitizers
  target_link_options(${PARSED_ARGS_NAME} PRIVATE ${cc_sanitizers})
endfunction(pio_add_target)

Kaynaklar